data2 = {{446, 651, 14850}, {382, 589, 15673}}
plot2 = ListPointPlot3D[data2,
ColorFunction -> Function[{x, y, z}, Hue[0.03, 1, 1]]]
f[x_, y_] = -11917.525 + 72.999*x - 0.061*x^2 + 32.143*y -
0.028102*(x*y) - 0.015041*y^2
plot1 = Plot3D[f[x, y], {x, 300, 600}, {y, 0, 800},
MeshStyle -> Directive[GrayLevel[0], Dotted], Mesh -> Automatic,
MeshFunctions -> Automatic,
PlotStyle -> Directive[GrayLevel[0], Opacity[0.264`]],
AxesLabel -> {"灌水量Irrigation amount(mm)",
"施肥量 Fertigation(kg.\!\(\*SuperscriptBox[\(hm\), \(-2\)]\))",
"产量Yield(kg.\!\(\*SuperscriptBox[\(hm\), \(-2\)]\))"},
PlotLabel -> Style[a.产量, a.Yield], PlotRange -> {0, 20000},
Boxed -> Dotted]
Show[plot1, plot2]
现在能力只能画成1中的图形，想把1图画成2图那样的形式。
很困惑，希望得到吧主大神帮助，非常感谢。

【求助】现在遇到两个难题
1. 坐标轴标签和坐标轴平行
2. 拟合方程后 其最大值的95%置信区间该怎么画（图中彩色部分）
恳请吧友各位大神指导，感谢万分！

Label方向可以用Rotate调，像这样：
data2 = {{446, 651, 14850}, {382, 589, 15673}};
f[x_, y_] = -11917.525 + 72.999*x - 0.061*x^2 + 32.143*y -
0.028102*(x*y) - 0.015041*y^2;
plot2 = ListPointPlot3D[data2,
ColorFunction -> Function[{x, y, z}, Hue[0.03, 1, 1]]];
plot1 = Plot3D[f[x, y], {x, 300, 600}, {y, 0, 800},
MeshStyle -> Directive[GrayLevel[0], Dotted], Mesh -> Automatic,
MeshFunctions -> Automatic,
PlotStyle -> Directive[GrayLevel[0], Opacity[0.264`]],
PlotRange -> {0, 20000},
PlotLabel -> Style["a.产量,a.Yield", Black, 20, Bold],
Axes -> True, AxesStyle -> Directive[Black, Thick],
TicksStyle -> Directive[Black, 16],
Ticks -> {Range[300, 600, 100], Range[0, 800, 200],
Range[0, 20000, 5000]},
BoxStyle -> Dashed, ImageSize -> 600];
Show[plot1,
AxesLabel -> (MapThread[
Rotate[Text@
Style[#1, 16,
TextAlignment ->
Center], #2] &, {{"灌水量\nIrrigation amount(mm)",
"施肥量\nFertigation/(kg\[CenterDot]\!\(\*SuperscriptBox[\(hm\), \
\(-2\)]\))",
"产量\nYield/(kg\[CenterDot]\!\(\*SuperscriptBox[\(hm\), \
\(-2\)]\))"}, {-30 \[Degree], 60 \[Degree], 90 \[Degree]}}])]
但是直接出来的效果不太好，label和坐标轴离得太远了，目测的方向也不是特别准，所以用个Manipulate细调一下参数，拖Locator调位置，拖Slider调角度，调好以后再画图导出就行了。
labels = {"灌水量\nIrrigation amount(mm)",
"施肥量\nFertigation/(kg\[CenterDot]\!\(\*SuperscriptBox[\(hm\), \(-2\
\)]\))", "产量\nYield/(kg\[CenterDot]\!\(\*SuperscriptBox[\(hm\), \
\(-2\)]\))"};
tmp = Manipulate[
plist = p;
\[Alpha]list = {\[Alpha]1, \[Alpha]2, \[Alpha]3};
Graphics[{Inset[plot1, Center, Center, Scaled[.8]],
MapThread[
Rotate[Text[
Style[#1, 16, TextAlignment -> Center],
#2], #
3] &, {labels,
plist, \[Alpha]list}]},
ImageSize -> 600, PlotRange -> {{-1, 1}, {-1, 1}, {-1, 1}}],
{{p, {{-.8, -.8}, {.8, -.8}, {-.8, .8}}}, Locator},
{{\[Alpha]1, -30 \[Degree]}, -\[Pi], \[Pi]},
{{\[Alpha]2, 60 \[Degree]}, -\[Pi], \[Pi]},
{{\[Alpha]3, 90 \[Degree]}, -\[Pi], \[Pi]}
]
(*调好参数以后再运行导出，直接导出图片质量比较差，建议导成pdf*)
Export["Yield.pdf",
Graphics[{Inset[plot1, Center, Center, Scaled[.8]],
MapThread[
Rotate[Text[
Style[#1, 16, TextAlignment -> Center],
#2], #
3] &, {labels,
plist, \[Alpha]list}]},
ImageSize -> 600, PlotRange -> {{-1, 1}, {-1, 1}, {-1, 1}}]]
最终结果

fmax = MaxValue[{f[x, y], 300 <= x <= 600 && 0 <= y <= 800}, {x, y}];
\[ScriptCapitalR] = ImplicitRegion[f[x, y] >= 0.95 fmax, {x, y}];
plot1 = Plot3D[f[x, y], {x, 300, 600}, {y, 0, 800},
MeshStyle -> Directive[GrayLevel[0], Dotted], Mesh -> Automatic,
MeshFunctions -> Automatic,
PlotStyle -> Directive[GrayLevel[0], Opacity[0.264`]],
PlotRange -> {0, 20000},
RegionFunction -> Function[{x, y, z}, z < 0.95 fmax],
PlotLabel -> Style["a.产量,a.Yield", Black, 20, Bold],
Axes -> True, AxesStyle -> Directive[Black, Thick],
TicksStyle -> Directive[Black, 16],
Ticks -> {Range[300, 600, 100], Range[0, 800, 200],
Range[0, 20000, 5000]},
BoxStyle -> Dashed, ImageSize -> 600];
plot3 = Plot3D[f[x, y], {x, y} \[Element] \[ScriptCapitalR],
Mesh -> None, ColorFunction -> "Rainbow",
PlotStyle -> Opacity[0.8`], PlotLegends -> Automatic];
Show[plot1, plot3]

data2 = {{446, 651, 14850}, {382, 589, 15673}};
f[x_, y_] = -11917.525 + 72.999*x - 0.061*x^2 + 32.143*y -
0.028102*(x*y) - 0.015041*y^2;
plot2 = ListPointPlot3D[data2,
ColorFunction -> Function[{x, y, z}, Hue[0.03, 1, 1]]];
plot1 = Plot3D[f[x, y], {x, 300, 600}, {y, 0, 800},
MeshStyle -> Directive[GrayLevel[0], Dotted], Mesh -> Automatic,
MeshFunctions -> Automatic,
PlotStyle -> Directive[GrayLevel[0], Opacity[0.264`]],
PlotRange -> {0, 20000}, Axes -> True,
AxesStyle -> Directive[Black, Thick],
TicksStyle -> Directive[Black, 16],
Ticks -> {Range[300, 600, 100], Range[0, 800, 200],
Range[0, 20000, 5000]}, BoxStyle -> Dashed, ImageSize -> 600];
fmax = MaxValue[{f[x, y], 300 <= x <= 600 && 0 <= y <= 800}, {x, y}];
\[ScriptCapitalR] = ImplicitRegion[f[x, y] >= 0.95 fmax, {x, y}];
plot3 = Plot3D[f[x, y], {x, y} \[Element] \[ScriptCapitalR],
Mesh -> None, ColorFunction -> "Rainbow",
PlotStyle -> Opacity[0.8`], PlotLegends -> Automatic];
Show[plot1, plot2, plot3,
AxesLabel -> (MapThread[
Rotate[Text@
Style[#1, 16,
TextAlignment ->
Center], #2] &, {{"灌水量\nIrrigation amount(mm)",
"施肥量\nFertigation/(kg\[CenterDot]\!\(\*SuperscriptBox[\(hm\), \
\(-2\)]\))",
"产量\nYield/(kg\[CenterDot]\!\(\*SuperscriptBox[\(hm\), \
\(-2\)]\))"}, {-30 \[Degree], 60 \[Degree], 90 \[Degree]}}])]
运用上面这种方法时，三个小图可以有机的组合在一起，但是用下面的代码和三个小图组合时，始终得不到想要的结果，是我顺序放错了吗或者是还有其他的原\
因，具体该怎么组合，请大神赐教，我是新手，麻烦您啦！
Show[plot1, plot2, plot3,
labels = {"灌水量\nIrrigation amount(mm)",
"施肥量\nFertigation/(kg\[CenterDot]\!\(\*SuperscriptBox[\(hm\), \
\(-2\)]\))",
"产量\nYield/(kg\[CenterDot]\!\(\*SuperscriptBox[\(hm\), \
\(-2\)]\))"};
tmp = Manipulate[plist = p;
\[Alpha]list = {\[Alpha]1, \[Alpha]2, \[Alpha]3};
Graphics[{Inset[plot1, Center, Center, Scaled[.8]],
MapThread[
Rotate[Text[
Style[#1, 16, TextAlignment -> Center], #2], #3] &, {labels,
plist, \[Alpha]list}]}, ImageSize -> 600,
PlotRange -> {{-1, 1}, {-1, 1}, {-1,
1}}], {{p, {{-.8, -.8}, {.8, -.8}, {-.8, .8}}},
Locator}, {{\[Alpha]1, -30 \[Degree]}, -\[Pi], \[Pi]}, \
{{\[Alpha]2, 60 \[Degree]}, -\[Pi], \[Pi]}, {{\[Alpha]3,
90 \[Degree]}, -\[Pi], \[Pi]}]

因为Manipulate不能放进Show里面，它的作用只是调整plist和alphalist参数
先单独运行Manipulate那句，调整好参数后 另起一个单元 运行Show的代码
或者如果你还是弄不清Manipulate的话，直接运行下面的代码
data2 = {{446, 651, 14850}, {382, 589, 15673}};
f[x_, y_] = -11917.525 + 72.999*x - 0.061*x^2 + 32.143*y -
0.028102*(x*y) - 0.015041*y^2;
plot2 = ListPointPlot3D[data2,
ColorFunction -> Function[{x, y, z}, Hue[0.03, 1, 1]]];
plot1 = Plot3D[f[x, y], {x, 300, 600}, {y, 0, 800},
MeshStyle -> Directive[GrayLevel[0], Dotted], Mesh -> Automatic,
MeshFunctions -> Automatic,
PlotStyle -> Directive[GrayLevel[0], Opacity[0.264`]],
PlotRange -> {0, 20000}, Axes -> True,
AxesStyle -> Directive[Black, Thick],
TicksStyle -> Directive[Black, 16],
Ticks -> {Range[300, 600, 100], Range[0, 800, 200],
Range[0, 20000, 5000]}, BoxStyle -> Dashed, ImageSize -> 600];
fmax = MaxValue[{f[x, y], 300 <= x <= 600 && 0 <= y <= 800}, {x, y}];
\[ScriptCapitalR] = ImplicitRegion[f[x, y] >= 0.95 fmax, {x, y}];
plot3 = Plot3D[f[x, y], {x, y} \[Element] \[ScriptCapitalR],
Mesh -> None, ColorFunction -> "Rainbow",
PlotStyle -> Opacity[0.8`]];
labels = {"灌水量\nIrrigation amount(mm)",
"施肥量\nFertigation/(kg\[CenterDot]\!\(\*SuperscriptBox[\(hm\), \
\(-2\)]\))",
"产量\nYield/(kg\[CenterDot]\!\(\*SuperscriptBox[\(hm\), \(-2\)]\))"};
plist = {{-0.232, -0.538`}, {0.698`, -0.372`}, {-0.905`, -0.008}};
\[Alpha]list = {-0.45238934211693027`, 60 \[Degree], 90 \[Degree]};
Legended[Graphics[{Inset[Show[plot1, plot2, plot3], Center, Center,
Scaled[.8]],
MapThread[
Rotate[Text[
Style[#1, 16, TextAlignment -> Center], #2], #3] &, {labels,
plist, \[Alpha]list}]
}, ImageSize -> 600, PlotRange -> {{-1, 1}, {-1, 1}, {-1, 1}}],
BarLegend[{"Rainbow", {0.95 fmax, fmax}}]]