(*如何检查一个表达式是否是广义上的字符串（可能被Style修饰过，也可能由StringJoin或Row拼接而成）*)
s1 = StringJoin@{"abc","def"};
s2 = Row@{"abc","def"};
s3 = Row@{"abc",Style["def",Red]};
s4 = Row@{Style["abc",Green],"def"};
s5 = Row@{Style["abc",Blue], Style["def",Pink]};
(*我有(广义上的)字符串s1~s5，我尝试写了RichStringQ，但他工作得不好。请赐教修改*)
RichStringQ[expr_]:=StringQ[expr]||MatchQ[expr,_[s_String,___]/;MemberQ[{Style,Row,Text},Head@expr]];
(*下句期望返回5个True，但实际得到{True,False,False,False,False}*)
Map[RichStringQ,{s1,s2,s3,s4,s5}]

自问自答：检查表达式每一层所有项的head，如果是String/Style/Text就停止，如果是Row就继续自我递归检查下一层，直到所有访问的项都True。
RichStringQ[expr_] := MatchQ[expr, u_ /;Which[
MemberQ[{String, Style, Text}, Head@u], True,
Head@u == Row, AllTrue[Map[RichStringQ, Flatten@Level[u, 1]], TrueQ]]];

嗯……在你的定义里
Clear[a]
Style[a, Red]
也算广义字符串？

可以去function repo看看有没有人写过？

这个问题其实用带模式限制的函数定义比较简单：
s1 = StringJoin@{"abc", "def"};
s2 = Row@{"abc", "def"};
s3 = Row@{"abc", Style["def", Red]};
s4 = Row@{Style["abc", Green], "def"};
s5 = Row@{Style["abc", Blue], Style["def", Pink]};
richQ[Row[a_, ___]] := And @@ richQ /@ a
richQ[Style[a_, ___]] := richQ@a
richQ[a_String] = True;
richQ[_] = False;
richQ /@ {s1, s2, s3, s4, s5}
(* 全True *)