我想将向量场 r sin(\[Theta])Overscript[\[CurlyPhi], ^] 从球坐标 {r,\[Theta],\[CurlyPhi]} 转化为直角坐标 {x,y,z}，并且保持场点仍以球坐标系表达，而场量以直角坐标系表达：
我可以分两步编程实现，代码如下：
In[
11
]:=
TransformedField[
"Cartesian" ->
"Spherical", #, {x, y, z} -> {r, \[Theta], \[CurlyPhi]}] & /@
TransformedField[
"Spherical" -> "Cartesian", {0, 0,
r Sin[\[Theta]]}, {r, \[Theta], \[CurlyPhi]} -> {x, y, z}]
Out[11]= {-r Sin[\[Theta]] Sin[\[CurlyPhi]],
r Cos[\[CurlyPhi]] Sin[\[Theta]], 0}
这种方式比较繁琐，TransformedField函数中可以通过某种设置一步完成吗？

最近在重看连续介质力学，仔细思考了一下这个问题，发现这个问题的最简解法应该是调用 CoordinateTransformData 函数的 OrthonormalBasisRotation 属性（标准正交基的旋转矩阵）：
β = CoordinateTransformData["Spherical" -> "Cartesian",
"OrthonormalBasisRotation", {r, θ, φ}]
(* {{Cos[φ] Sin[θ], Sin[θ] Sin[φ], Cos[θ]},
{Cos[θ] Cos[φ], Cos[θ] Sin[φ], -Sin[θ]},
{-Sin[φ], Cos[φ], 0}} *)
{0, 0, r Sin[θ]} . β
(* {-r Sin[θ] Sin[φ], r Cos[φ] Sin[θ], 0} *)
(* 顺带说一句这个 β 也可以用更基本的方法算出来：*)
coords = FromSphericalCoordinates[{r, θ, φ}]
(* {r Cos[φ] Sin[θ], r Sin[θ] Sin[φ], r Cos[θ]} *)
(* 雅可比阵其实也可以从 CoordinateTransformData 里调出来。不过这里是在演示背后的数理，就直接算了。 *)
jac = D[coords, {{r, θ, φ}}]
(* {{Cos[φ] Sin[θ], r Cos[θ] Cos[φ], -r Sin[θ] Sin[φ]},
{Sin[θ] Sin[φ], r Cos[θ] Sin[φ], r Cos[φ] Sin[θ]},
{Cos[θ], -r Sin[θ], 0}} *)
(* 度规（以及伸缩系数/拉梅系数）也可以从 CoordinateChartData 里调出来。 *)
metric = jac\[Transpose] . jac // Simplify
(* {{1, 0, 0}, {0, r^2, 0}, {0, 0, r^2 Sin[θ]^2}} *)
Simplify[
Inverse[Sqrt[metric]] . jac\[Transpose], {r > 0, 0 < θ < Pi}]
% == β
(* {{Cos[φ] Sin[θ], Sin[θ] Sin[φ], Cos[θ]},
{Cos[θ] Cos[φ], Cos[θ] Sin[φ], -Sin[θ]},
{-Sin[φ], Cos[φ], 0}} *)
(* True *)

其实还可以玩得更花一些：
coords = FromSphericalCoordinates[{r, θ, φ}]
(* {r Cos[φ] Sin[θ], r Sin[θ] Sin[φ], r Cos[θ]} *)
jac = D[coords, {{r, θ, φ}}]
(* {{Cos[φ] Sin[θ], r Cos[θ] Cos[φ], -r Sin[θ] Sin[φ]},
{Sin[θ] Sin[φ], r Cos[θ] Sin[φ], r Cos[φ] Sin[θ]},
{Cos[θ], -r Sin[θ], 0}} *)
metric = jac\[Transpose] . jac // Simplify
(* {{1, 0, 0}, {0, r^2, 0}, {0, 0, r^2 Sin[θ]^2}} *)
sf = Simplify[Sqrt[Diagonal@metric], {r > 0, 0 < θ < Pi}]
(* {1, r, r Sin[θ]} *)
MakeBoxes[pd[x_], _] :=
TemplateBox[{ToBoxes@x}, "pd",
DisplayFunction -> (FractionBox["∂",
RowBox@{"∂", #}] &)]
vec = {0, 0, r Sin[θ]} . (1/sf pd /@ {r, θ, φ})
(* pd[φ] *)
vecCartesian = vec /. pd[X_] :> D[coords, X] . pd /@ {x, y, z} // Expand
(* r Cos[φ] pd[y] Sin[θ] - r pd[x] Sin[θ] Sin[φ] *)
CoefficientArrays[vecCartesian, pd /@ {x, y, z}] // Last // Normal
(* {-r Sin[θ] Sin[φ], r Cos[φ] Sin[θ], 0} *)
要理解上述计算，需要一些一般化的张量的知识。（连续介质力学教材涉及的通常只是 笛卡尔张量。）