用同一个workbook中sheet1的A列7行开始以下所有的vendor code在sheet2的内容中搜索 如果没有这个code 就pass
如果有 继续判断该code的h列内容是否为JQ 、不是的话pass。是的话 要提示（比如整列标红）、完全没思路呀 大佬们

不知道你代码写到哪步了，具体卡在哪里不会；其实你说的就是思路，只要按照思路一步步实现就行了；用sheets("工作表名称")引用对应工作表，定义一个变量i用for做循环，用range("数据范围")引用对应单元格，用range的value属性可以取到单元格的值，用range的find方法可以查找有对应值的单元格，用range的row属性可以获得单元格所在行，判断用if单元格值="要比较的值"，用range的entirecolumn属性引用单元格所在的整列，用range的interior的colorindex属性来设置单元格背景色，循环到有数据的最后一行就行了，可以用range的end(xlup)方法获得，如果有不明白的可以百度搜对应属性或方法的使用方法，另外善用录制宏功能可以让你事半功倍。

绞尽脑汁 写成这样 大佬们请开喷吧 完全运行不了 好像这个赋值不对

Range("Ai") 是什么
dlfh类型的类型是 string? range？
那个d是要干啥

Option Explicit
Sub CheckJQ()
　　Dim VenderCodeSheet As Worksheet, FindSheet As Worksheet, Row As Long, VenderCode As String, FindCell As Range, FirstFindCellAddress As String
　　Set VenderCodeSheet = Sheets(1) '设置CenderCode所在表
　　Set FindSheet = Sheets(2) '设置要查找的表
　　With VenderCodeSheet
　　　　For Row = 7 To .Range("A" & .Rows.Count).End(xlUp).Row '从第7行开始循环，直到A列不为空的最后一行
　　　　　　VenderCode = .Range("A" & Row).Value '取A列当前行的VenderCode值
　　　　　　With FindSheet.UsedRange '设置查找范围
　　　　　　　　Set FindCell = .Find(VenderCode) '执行查找
　　　　　　　　If Not FindCell Is Nothing Then '如果找到了
　　　　　　　　　　FirstFindCellAddress = FindCell.Address '保存第一个找到的单元格地址
　　　　　　　　　　Do '循环查找
　　　　　　　　　　　　If .Range("H" & FindCell.Row).Value = "JQ" Then '判断找到的单元格同行的H列是否为JQ
　　　　　　　　　　　　　　FindCell.EntireColumn.Interior.Color = vbRed '如果是就标记找到的单元格整列背景为红色
　　　　　　　　　　　　End If
　　　　　　　　　　　　Set FindCell = .FindNext(FindCell) '从当前位置继续查找
　　　　　　　　　　Loop Until FindCell.Address = FirstFindCellAddress '直到回到第一个找到的单元格为止
　　　　　　　　End If
　　　　　　End With
　　　　Next Row
　　End With
　　MsgBox "VenderCode查找完毕"
End Sub

把表2数据写入字典，然后循环表1，就直接得出结果了。

不知道你要匹配表2的哪一列数据。

这个bug 怎么解决呀

@娜乌_西卡 这里报了bug、另外上一句 取下端单元格的话 是不是应该xldown呀

Sub q47436528()
Dim arr, d, i, s
Set d = CreateObject("scripting.dictionary")
arr = ThisWorkbook.Sheets("sheet2").UsedRange
For i = 2 To UBound(arr)
If arr(i, 1) = "" Then GoTo line
d(arr(i, 1)) = arr(i, 8)
line:
Next i
arr = ThisWorkbook.Sheets("sheet1").UsedRange
For i = 7 To UBound(arr)
s = arr(i, 1)
If s = "" Then GoTo line1
If Not d.exists(s) Then GoTo line1
If d(s) = "JQ" Then
Cells(i, 1).Interior.ColorIndex = 6
End If
line1:
Next i
End Sub

Sub CompareAndHighlightUsingDictionary()
Dim ws1 As Worksheet
Dim ws2 As Worksheet
Dim lastRow1 As Long
Dim lastRow2 As Long
Dim i As Long
Dim key As Variant
Dim dict As Object
' 设置工作表
Set ws1 = ThisWorkbook.Sheets("Sheet1")
Set ws2 = ThisWorkbook.Sheets("Sheet2")
' 获取两个工作表中最后一行的行号
lastRow1 = ws1.Cells(ws1.Rows.Count, "A").End(xlUp).Row
lastRow2 = ws2.Cells(ws2.Rows.Count, "A").End(xlUp).Row
' 创建字典对象
Set dict = CreateObject("Scripting.Dictionary")
' 将表二的A列和B列数据存入字典
For i = 1 To lastRow2
key = ws2.Cells(i, 1).Value & "|" & ws2.Cells(i, 2).Value
dict(key) = i
Next i
' 遍历表一的数据，进行比较并标记
For i = 1 To lastRow1
key = ws1.Cells(i, 1).Value & "|" & ws1.Cells(i, 2).Value
If dict.exists(key) Then
' 标记表一和表二的相同行为红色
ws1.Rows(i).网页链接 = RGB(255, 0, 0)
ws2.Rows(dict(key)).网页链接 = RGB(255, 0, 0)
End If
Next i
End Sub