这个透视一下，再复制出来调整列位置不就可以么

可以。
Sub zd()
[H2:M65535].ClearContents
n = [a65535].End(xlUp).Row
Cells(2, "H") = Cells(2, "A")
Cells(2, "I") = Cells(2, "B")
Cells(2, "L") = Cells(2, "E")
Cells(2, "M") = Cells(2, "F")
k = 2
For i = 3 To n
found = 0
For j = 2 To k
If Cells(i, "A") = Cells(j, "H") And Cells(i, "B") = Cells(j, "I") Then
found = 1
Exit For
End If
Next j
If found = 0 Then
k = k + 1
Cells(k, "H") = Cells(i, "A")
Cells(k, "I") = Cells(i, "B")
Cells(k, "L") = Cells(i, "E")
Cells(k, "M") = Cells(i, "F")
End If
Next i
For i = 2 To n
found = 0
For j = 2 To k
If Cells(i, "A") = Cells(j, "H") And Cells(i, "B") = Cells(j, "I") Then
Cells(j, "J") = Cells(j, "J").Value + Cells(i, "C").Value
Cells(j, "K") = Cells(j, "K").Value + Cells(i, "D").Value
End If
Next j
Next i
End Sub

有个问题，例如描述1列，如果单号物料号都一致的多行记录，凑巧在描述1列录入内容有差异，那你的描述1列想如何处理呢？

Option Explicit
Sub abc()
　Dim a, i, j, d, t, m
　a = [a1].CurrentRegion.Offset(1).Value
　Set d = CreateObject("scripting.dictionary")
　For i = 1 To UBound(a) - 1
　　t = a(i, 1) & a(i, 2)
　　If d.exists(t) Then
　　　For j = 3 To 4
　　　　a(d(t), j) = a(d(t), j) + a(i, j)
　　　Next
　　Else
　　　m = m + 1: d(t) = m
　　　For j = 1 To UBound(a, 2)
　　　　a(m, j) = a(i, j)
　　　Next
　　End If
　Next
　[a1].Offset(1, UBound(a, 2) + 1).Resize(m, UBound(a, 2)) = a
End Sub

字典多字段求和要结合使用数组才行。

'如果A、B列有序而且行数挺多（至少10^5）,这方法会比字典快得多，而且它的效率是线性的。而字典key当多余一定数量时效率会急速下降的。
Option Explicit
Sub abc()
　Dim a, i, j, t, m, p, n(7)
　a = Range("a2:g" & Cells(Rows.Count, "a").End(xlUp).Row + 1).Value
　For i = 1 To UBound(a) - 1
　　a(i, 7) = a(i, 1) & a(i, 2)
　Next
　For i = 1 To UBound(a) - 1
　　For j = 3 To 4
　　　n(j) = n(j) + a(i, j)
　　Next
　　If a(i, 7) <> a(i + 1, 7) Then
　　　m = m + 1
　　　For j = 1 To UBound(a, 2)
　　　　a(m, j) = a(p + 1, j)
　　　Next
　　　For j = 3 To 4
　　　　a(m, j) = n(j)
　　　　n(j) = 0
　　　Next
　　　p = i
　　End If
　Next
　[a1].Offset(1, UBound(a, 2)).Resize(m, UBound(a, 2) - 1) = a
End Sub