我正常操作是选中要排序的区域，然后在像图二那样点排序，有很多，能不能弄一个宏，我选择要排序的区域后在运行宏就可以。

排序优先级是CDFE

'可以指定列次序排序，列数可以不限
Option Explicit
Sub abc()
　Dim a, pos, i, j, k, p
　a = [a1].CurrentRegion.Offset(1).Value
　pos = Array(3, 4, 6, 5) 'C、D、F、E 列次序升序
　Call bsort(a, 1, UBound(a, 1) - 1, 1, UBound(a, 2), pos(0))
　For i = 1 To UBound(pos)
　　p = 0
　　For j = 1 To UBound(a, 1) - 1
　　　For k = i - 1 To 0 Step -1
　　　　If a(j, pos(k)) <> a(j + 1, pos(k)) Then
　　　　　Call bsort(a, p + 1, j, 1, UBound(a, 2), pos(i))
　　　　　p = j: Exit For
　　　　End If
　　　Next
　　Next
　Next
　[a1].Offset(1, UBound(a, 2) + 1).Resize(UBound(a, 1) - 1, UBound(a, 2)) = a
End Sub
Function bsort(a, first, last, left, right, key)
　Dim i, j, k, t
　For i = first To last - 1
　　For j = first To last + first - 1 - i
　　　If a(j, key) > a(j + 1, key) Then
　　　　For k = left To right
　　　　　t = a(j, k): a(j, k) = a(j + 1, k): a(j + 1, k) = t
　　　　Next
　　　End If
　　Next
　Next
End Function

录制宏

软件的基础功能不就是你的需求解决办法吗？为啥要另外弄个，似乎多此一举啊

'限定6列数据排序,纯数据不带标题
Option Explicit
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
　If Target.Rows.Count < 2 Or Target.Columns.Count <> 6 Then Exit Sub
　If Target.Rows.Count = Rows.Count Then Exit Sub
　Dim x, y, a, i, j, k, p, pos
　x = Target.Row: y = Target.Column
　a = Cells(x, y).Resize(Target.Rows.Count + 1, 6).Value
　pos = Array(3, 4, 6, 5) '后4列
　Call qsort(a, 1, UBound(a, 1) - 1, 1, 6, pos(0))
　For i = 1 To UBound(pos)
　　p = 0
　　For j = 1 To UBound(a, 1) - 1
　　　For k = i - 1 To 0 Step -1
　　　　If a(j, pos(k)) <> a(j + 1, pos(k)) Then
　　　　　If j - p > 2 Then Call qsort(a, p + 1, j, 1, 6, pos(i))
　　　　　p = j: Exit For
　　　　End If
　　　Next
　　Next
　Next
　Application.EnableEvents = False
　Cells(x, y).Resize(UBound(a, 1) - 1, 6) = a
　Application.EnableEvents = True
End Sub
Function qsort(a, first, last, left, right, key)
　Dim i As Long, j As Long, k As Long, x, t
　i = first: j = last: x = a((first + last) \ 2, key)
　While i <= j
　　While a(i, key) < x: i = i + 1: Wend
　　While x < a(j, key): j = j - 1: Wend
　　If i <= j Then
　　　For k = left To right
　　　　t = a(i, k): a(i, k) = a(j, k): a(j, k) = t
　　　Next
　　　i = i + 1: j = j - 1
　　End If
　Wend
　If first < j Then qsort a, first, j, left, right, key
　If i < last Then qsort a, i, last, left, right, key
End Function

Sub 这个能排3个和3个以下key()
With Selection
.Sort .Cells(1, 1), 1, .Cells(1, 2), , 1, .Cells(1, 3), 1, 0
End With
End Sub
=================================================
Sub 超过3个key用这个()
Selection.Offset(-1).Resize(1 + Selection.Rows.Count).AutoFilter
With ActiveSheet.AutoFilter.Sort
With .SortFields
.Clear
.Add2 Key:=Selection.Columns(1)
.Add2 Key:=Selection.Columns(2)
.Add2 Key:=Selection.Columns(3)
.Add2 Key:=Selection.Columns(4)
End With
.Apply
End With
Selection.AutoFilter
End Sub