怎么在绘制等高线图的时候让等高线在标签处断开，像下图这样
ContourPlot[Cos[\[Pi]/4 (x + 1)] Cos[\[Pi] y], {x, -1, 1}, {y, -1, 1},
ColorFunction -> (Transparent &),
ContourLabels -> (Text[
#3, {#
1, #2}, Background -> White] &)
]
但是不会像下面这样盖住绘制的颜色？
ContourPlot[Cos[\[Pi]/4 (x + 1)] Cos[\[Pi] y], {x, -1, 1}, {y, -1, 1},
ColorFunction -> "SunsetColors",
ContourLabels -> (Text[
#3, {#
1, #2}, Background -> White] &)
]

label是通过图元实现的，而label所在位置会有不同背景色的两个区域和一条界限。很难在graphics层面解决此问题，在image层面处理此问题可能容易些。

也许在图2的基础上用PS处理一下会更好？
也就是从像素的角度考虑，比如一个简陋的示意：
ContourPlot[Cos[\[Pi]/4 (x+1)] Cos[\[Pi] y],{x,-1,1},{y,-1,1},ColorFunction->(Transparent&),ContourLabels->(Text[
#3,{#
1,#2},Background->White]&)]//Rasterize;
ContourPlot[Cos[\[Pi]/4 (x+1)] Cos[\[Pi] y],{x,-1,1},{y,-1,1},ColorFunction->"SunsetColors",ContourStyle->None]//Rasterize;
ImageMultiply[%%,%]

讲道理我觉得这种画法只适合无色等高线图。不过好不好看终究是主观的东西，这里就不多议论了。
纯在Graphics层面解决不算很难。思路很简单：提取标签的坐标，然后基于这些坐标，返回去把多余的等高线在生成阶段挖掉，最后三幅图合在一起：
wholereg = Rectangle[{-1.1, -1.1}, {1.1, 1.1}];
expr = Cos[π/4 (x + 1)] Cos[π y];
cp = ContourPlot[expr, {x, y} ∈ wholereg, ColorFunction -> (Transparent &),
ContourLabels -> (Text[
#3, {#
1, #2}, Background -> White] &), PlotPoints -> 100]
text = Cases[cp, Text[c_, coord__, _] :> Text[c, coord], Infinity];
coord = text[[All, 2]];
reg = RegionDifference[wholereg, RegionUnion @@ (Ellipsoid[#, {0.05, 0.04}] & /@ coord)];
(* 实践发现先把区域离散再画图更快，至少版本12.2是如此 *)
disreg = DiscretizeRegion[reg, MaxCellMeasure -> 0.005]
cpbroken = ContourPlot[expr, {x, y} ∈ disreg, ColorFunction -> (Transparent &),
PlotPoints -> 100]
cpbg = ContourPlot[expr, {x, y} ∈ wholereg, ColorFunction -> "SunsetColors",
ContourStyle -> None, PlotPoints -> 50];
Show[cpbg, cpbroken, Graphics@text]