公式求助，如何把工龄转化为小数 - excel吧

level 1

海拉鲁拉人拉货林师傅楼主

有的是xx年，有的是xx年xx月。
请问怎么转化为x.x的格式。
比如3年6月转化为3.5，后面不需要加年字。
或者有什么办法可以把年不带月份的加上0月，比如把1年转化为1年0月，这样我就能用一个已经找到的公式了。

2020年12月09日 11点12分 1

level 4

san棠果

年替换"."（点），月替换“”（空格），6年5月替换成6.5

2020年12月09日 16点12分 2

ssg365

这算法....5个月是半年？那6年11个月就是6.11年喽？

2020年12月10日 10点12分

level 11

😐开心每一天

算工龄肯定有个入职日期，你重新用text不就行了

2020年12月09日 23点12分 3

level 13

ssg365

你范例中，都会有“年”字，

2020年12月09日 23点12分 4

level 15

dtafwqs808

J3=ROUND(MID(I3,1,FIND("年",I3)-1)+IF(RIGHT(I3,1)<>"月",0,MID(I3,FIND("年",I3)+1,FIND("月",I3)-FIND("年",I3)-1)/12),1)

2020年12月10日 06点12分 5

海拉鲁拉人拉货林师傅

谢谢大神，但是这样算出来只保留了一位小数不够准确，比如5个月算出来是0.4年，但如果保留两位小数的话5个月应该是0.42年。公式里我看不出来哪里是小数位数。从数据格式改也没有用。

2020年12月10日 10点12分

level 13

ssg365

=ROUND(LEFT(A1,FIND("年",A1)-1)+MAX(--TEXT(MID(A1,FIND("年",A1)+1,{1,2}),"0;;0;!0"))/12,2)&"年"

2020年12月10日 12点12分 6

海拉鲁拉人拉货林师傅

感谢

2020年12月11日 01点12分

level 13

ssg365

顺带回答第二问，统一转化为x年x个月的格式
=A1&REPT("0个月",ISERR(FIND("月",A1)))

2020年12月10日 12点12分 7

level 9

梁州倦客

=IFERROR(--TEXT(A2,"y"),0)+IFERROR(TEXT(A2,"m")/12,0)

2020年12月11日 06点12分 8

level 7

活宝械

=EVALUATE(SUBSTITUTE(SUBSTITUTE(A1,"年","+0"),"个月","/12"))

2020年12月11日 07点12分 10

活宝械

这个是个名称，需要定义一个名称，然后在需要输入公式的单元格直接输入这个名称的名字就行了

2020年12月11日 07点12分

level 7

活宝械

效果是这样的：

2020年12月11日 07点12分 11

level 4

树尖梢上的苹果

TEXT(IFERROR(LEFT(A2,FIND("年",A2)-1),0)+IFERROR(MID(A2,FIND("年",A2)+1,FIND("月",A2)-FIND("年",A2)-1),0)/12,"00.00")

2020年12月11日 07点12分 12

level 7

活宝械

LEFT(A4,FIND("年",A4)-1)-IFNA(LOOKUP(,-MID(A4,FIND("年",A4)+1,ROW($1:$2))),)/12

2020年12月11日 08点12分 14