If App.PrevInstance = True Then end '防止程序重复运行
这句是可以防止程序多次运行的
但我现在同时想加上：如果程序在进程中，双击这个EXE时，程序显示出来（程序默认是隐藏的me.hide），还不会再运行一个进程，应该怎么写？使用 me.show后程序是显示了，但同时进程就多一个
If App.PrevInstance = True Then Me.Show

App.PrevInstance独开有缺点，exe复制一份到其他目录就可以打开运行多个，解决方案：
1.CreateMutex、CreateSemaphore等创建互斥体实现单开，然后EnumWindow枚举窗口，比较类名或窗口名，确认是该窗口的则显示(还可以用SetProp等函数)
2.CreateFileMapping文件映射实现(第一次运行时写入窗体句柄，第二次运行时读取句柄显示窗口)，这个推荐
当然还有很多方法，这个得你自己去尝试

不可用App.PrevInstance，用窗口，给你主窗口设置一个特殊caption作为flag，运行后查找这个窗口，找到了就showWindow该窗口，再退出自己。

最简单的方法是：

form_load事件在c盘某文件里记录自己的窗口句柄。
程序启动，窗口没创建之前，判断这个窗口句柄是否有效，如果有效，显示，退出。如果无效，创建窗口，继续向文件写入当前窗口句柄，这样不管程序是否正常退出都没问题，
不过有很小的可能，在你程序退出后win为其他窗口分配与文件内相同的句柄，这样会导致你的程序打不开。文可能性非常小

找到了一个代码
https://zhidao.baidu.com/question/25789597.html
就是用来检测进程的，有就强退那个进程，测试可以用，但感觉有点大材小用了，我感觉应该有更简洁的代码可以实现我的效果吧

新建一个标准模块，代码如下
Option Explicit
Private Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpDefault As String, ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long
Private Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpString As Any, ByVal lpFileName As String) As Long
Private Declare Function SendMessageA Lib "user32" (ByVal Handle As Long, ByVal msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Private Declare Function IsWindow Lib "user32" (ByVal Handle As Long) As Boolean
Private Declare Sub SetForegroundWindow Lib "user32" (ByVal Handle As Long)
Public Function IniRead(ByVal IniPath As String, ByVal Field As String, ByVal key As String, Optional ByVal DefaultKeyValue As Variant) As String
Dim s As String * 255, s2 As String * 255
GetPrivateProfileString Field, key, DefaultKeyValue, s, 255, IniPath
If s = s2 Then
IniRead = CStr(DefaultKeyValue)
Else
IniRead = Trim(Replace(s, Chr(0), ""))
End If
End Function
Public Function IniWrite(IniPath As String, Field As String, key As String, KeyValue As String) As String
WritePrivateProfileString Field, key, KeyValue, IniPath
End Function
Public Sub Main()
Dim Hwnd As Long
Hwnd = IniRead("d:\vbMainConfig.ini", "hwnd", "hwnd", "0")
If IsWindow(Hwnd) Then
SendMessageA Hwnd, 274, 61728, 0
SetForegroundWindow Hwnd
Else
Form1.Show
End If
End Sub
程序主窗体的 load事件
Private Sub Form_Load()
IniWrite "d:\vbMainConfig.ini", "Hwnd", "Hwnd", CStr(Me.Hwnd)
End Sub
最后，工程-属性-通用-启动对象 设为 Sub Main 编译后运行看看效果

句柄 hook钩子---了解一下。

'放一个Label控件，工程名为工程1，Form1的LinkTopic为Form1，LinkMode为1
方法1：
Option Explicit
Private Sub Form_Initialize()
If App.PrevInstance Then
Call DDESendMessage("Activate")
End
End If
End Sub
'DDE发送消息
Private Sub DDESendMessage(ByVal strMsg As String)
label1.LinkTopic = "工程1|Form1"
label1.LinkMode = vbLinkManual
Call label1.LinkExecute(strMsg)
End Sub
Private Sub Form_LinkExecute(CmdStr As String, Cancel As Integer)
Me.WindowState = 0
Cancel = False
End Sub
方法2：
Option Explicit
Private Sub Form_Initialize()
If App.PrevInstance Then
Label1.LinkTopic = "工程1|Form1"
Label1.LinkMode = vbLinkManual
End
End If
End Sub
Private Sub Form_LinkOpen(Cancel As Integer)
Me.WindowState = 0
End Sub
以前写的DDE激活，也能满足你的要求