好难啊，我看不懂英文

问题 1 ：
'　斐波那契数列
Option Explicit
Dim cc, i, n, Fn, F1, F2
cc = "请输入斐波那契数列的项数 n = ?"
n = InputBox(cc, "输入 n", 10)
cc = "1．0" & vbCrLf & "2．1"
If n >= 3 Then
F1 = 1: F2 = 0
For i = 3 To n
Fn = F1 + F2
cc = cc & vbCrLf & i & "．" & Fn
F2 = F1: F1 = Fn
Next
End If
MsgBox cc, 0 + 64, "斐波那契数列"

问题 2 ：
计算余弦函数的值，
当 x = 30° ， n = 2、3、4、5 时，计算出一张表格，并求出相对误差（%）。

Option Explicit
Private Sub Form_Load()
Call 清除
End Sub
'　保留八位小数
Public Function cc(ByVal ss As Double) As String
cc = CStr(0.00000001 * Int(ss * 100000000 + 0.5))
If Mid(cc, 1, 1) = "." Then cc = "0" & cc
If Mid(cc, 1, 2) = "-." Then cc = "-0" & Mid(cc, 2)
End Function
'　阶乘函数 n! = nJC(n)
Public Function nJC(ByVal n As Integer) As Double
Dim j As Integer
nJC = 1
For j = 2 To n: nJC = nJC * j: Next
End Function
'　余弦函数 Cos(x) = F_Cos(x, n) 【x 是弧度制】
Public Function F_Cos(ByVal x As Double, _
ByVal n As Integer) As Double
Dim i As Integer, k As Integer, nFH As Integer
nFH = 1: F_Cos = 1
For i = 2 To n
nFH = nFH * (-1): k = 2 * (i - 1)
F_Cos = F_Cos + nFH * x ^ k / nJC(k)
Next
End Function
Private Sub 计算()
Dim s1 As Double, s2 As Double
Dim x As Double, dd As Double
Dim i As Integer
x = 30 * 0.0174533 '　转换成弧度制
s2 = Cos(x): Text3.Text = CStr(cc(s2))
For i = 2 To 5
s1 = F_Cos(x, i)
dd = Abs((s1 - s2) / s1 * 100)
Text1(i - 2).Text = CStr(cc(s1))
Text2(i - 2).Text = CStr(cc(dd))
Next
End Sub
Private Sub 清除()
Dim i As Integer
For i = 0 To 3
Text1(i).Text = ""
Text2(i).Text = ""
Next
Text3.Text = ""
End Sub
Private Sub Command1_Click(Index As Integer)
Select Case Index
Case 0: Call 计算
Case 1: Call 清除
Case 2: Unload Me: End
End Select
End Sub
Private Sub Command1_MouseMove(Index As Integer, _
Button As Integer, Shift As Integer, _
x As Single, Y As Single)
Command1(Index).SetFocus
End Sub