各位大佬好，我写了一个bat，但是执行的时候似乎判断没有生效，麻烦大佬帮我看看问题在哪
要求很简单，我是准备放在系统的启动项里，每天开机判断当前时间，如果是早上7点到9点之间，就自动改IP，其余时间IP自动获取，if 和 else 里面的内容可以单独执行，就是外面的判断好像有有问题
@echo off
echo 当前时间为%time:~0,2%
if "%time:~0,2%" GEQ "7" if "%time:~0,2%" LEQ "9" (
echo 设置为办公IP地址
:netsh interface ip set address 以太网 static XXXXXX
:netsh interface ip set dns 以太网 static XXXXXX
:netsh interface ip add dns 以太网 XXXXXX
echo 按任意键退出 & pause>nul
exit
)else(
echo 设置为自动获取IP
:netsh interface ip set address 以太网 dhcp
echo 按任意键退出 & pause>nul
exit
)

两层if没有嵌套

生活要想过得去，身上必须沾点绿。

去掉下面这句里的引号：
if "%time:~0,2%" GEQ "7" if "%time:~0,2%" LEQ "9"
改成
if %time:~0,2% GEQ "7" if %time:~0,2% LEQ 9
因为10点之前 %time:~0,2% 的结果是两个字符：空格+小时，
带引号的话就是判断 " 7" GEQ "7"了。

还有一点，7点到9点之间，似乎是指7点整到9点整之间吧。
LEQ 9 会把9点到10点之间也算上，应该是LSS ...

@echo off
echo 当前时间为%time:~0,2%
if %time:~0,2% GEQ 7 if %time:~0,2% LSS 9 (
echo 设置为办公IP地址
:netsh interface ip set address 以太网 static 172.18.23.178 255.255.255.192 172.18.23.129
:netsh interface ip set dns 以太网 static 202.102.192.68
:netsh interface ip add dns 以太网 202.102.192.68 index=2
echo 按任意键退出 & pause>nul
exit
)else(
echo 设置为自动获取IP
:netsh interface ip set address 以太网 dhcp
echo 按任意键退出 & pause>nul
exit
)

if还能这么用的？

为什么netsh前面会有冒号？

这楼主，哎，算了，不说啥了，看我一记洛阳铲！

)else(改为) else (
:netsh改为rem netsh
即可

@echo off
echo 当前时间为%time:~0,2%
if 1%time:~0,2% GEQ 107 (
if 1%time:~0,2% LSS 109 (
echo 设置为办公IP地址
netsh interface ip set address 以太网 static 172.18.23.178 255.255.255.192 172.18.23.129
netsh interface ip set dns 以太网 static 202.102.192.68
netsh interface ip add dns 以太网 202.102.192.68 index=2
ipconfig /renew
ipconfig /flushdns
echo 按任意键退出 & pause>nul
exit
))
echo 设置为自动获取IP
netsh interface ip set address 以太网 dhcp
ipconfig /renew
ipconfig /flushdns
echo 按任意键退出 & pause>nul
exit

if右边 括号不可省略(尤其是包含换行时)，左右括号数量也必须对上
) else ( 空格不可省略
else不懂就不要瞎写

还有，你改了ip不刷新配置等于白改

ip修改命令也是瞎写，你这样根本改不了吧