@echo off&Setlocal enabledelayedexpansion
::作者 小程936 QQ1781047213
call :vbs
set ch= 1234567890ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz
set umu=ASSOC ATTRIB BREAK BCDEDIT CACLS CALL CD CHCP CHKDSK CHKNTFS CHOICE CLS CMD COLOR COMP COMPACT CONVERT COPY DATE DEL DIR DISKPART DISM DOSKEY DRIVERQUERY ECHO ENDLOCAL EXIT FC FIND FINDSTR FOR FORMAT FSUTIL FTYPE GOTO GPRESULT GRAFTABL HELP ICACLS IF LABEL MD MKLINK MODE MORE MOVE NET OPENFILES PATH PAUSE POPD PRINT PROMPT PUSHD RD RECOVER REG REM REN REPLACE ROBOCOPY SET SETLOCAL SC SCHTASKS SHIFT SHUTDOWN SORT START SUBST SYSTEMINFO TASKLIST TASKKILL TIME TITLE TREE TYPE VER VERIFY VOL XCOPY WMIC
set um2=DISKPART DISM NET
reg query "HKU\S-1-5-19" >nul 2>&1 &&set adm=1||set adm=0
REM 针对特殊命令的优化计划 LOCAL-SET- POPD-PUSHD (ECHO+?&EXIT)|DISKPART net
echo A-Z搜索命令 1首选 2末选 5退出 9帮助 0清屏 空格翻页
:so
if DEFINED so (title %so% - soBAT) else title soBAT
CHOICE /C%ch% /N /CS /T 35 /D 0
(set /a er=%ERRORLEVEL%)&if %ERRORLEVEL% GTR 36 call cap.vbs
if %er% LEQ 10 cls&goto num
set so=%so%!ch:~%ER%,1!
set /a n+=1,sn=0
call :soso
goto so
:0
set so=&set n=&title soBAT&goto :eof
:soso
cls
for %%z in (%umu%) do (set zz=%%z&if /I "!so:~,%n%!" == "!zz:~,%n%!" (set szz=%%z&goto sosoc))
:sosoc
for %%z in (%umu%) do (set zz=%%z&if /I "!so:~,%n%!" == "!zz:~,%n%!" (echo %%z&set sz=%%z&set /a sn+=1))
if %sn%==1 call :data %sz%
if %sn%==0 ((call :0)&goto :eof)
if /i %szz%==%so% echo 按1选择%szz%
goto :eof
:小程936
if /I %1 == DISKPART (if %adm%==1 ((ECHO+?&EXIT)|DISKPART) else echo 权限不足，拒绝访问)|more
if /I %1 == DISM (if %adm%==1 (DISM /?) else echo 权限不足，拒绝访问)|more
if /I %1 == NET (%1 HELP)|more
echo+&goto :eof
:data
title %1 - soBAT - 空格键翻页
for %%z in (%um2%) do if /i "%%z" == "%1" ((call :小程936 %1)&(call :0)&(goto :eof))
if EXIST %1.txt (more %1.txt) else ((%1 /?&echo+)|more)
call :0
goto :eof
:vbs
pushd "%~pd0"
md he 2>nul
cd he||(echo 权限不足，无法初始化&pause>nul&exit /b 1)
>cap.vbs echo Set obb = CreateObject^(^"Wscript.Shell^"^)
>>cap.vbs echo obb.SendKeys^"^{CAPSLOCK^}^"
>ti.vbs echo Wscript.Sleep Wscript.Arguments^(0^)
set n=
goto :eof
:num
if %er%==1 call :data %szz%
if %er%==2 call :data %sz%
if %er%==5 exit /b
if %er%==9 echo A-Z搜索命令 1首选 2末选 5退出 9帮助 0清屏 空格翻页
if %er%==10 call :0
goto so

1年前写的，算是个坑但毕竟还能用，而且效果不错

谁愿意试试保证会喜欢上的，

@bat大人 试一试如何？

bat初学者必备神器系列

补充:支持自定义命令帮助，优先级比系统帮助高 保存在 本批处理所在路径/he/命令名.txt
添加新命令的话，在第四行set umc=加一个即可

嗯，想法不错，UI有点让人眼花缭乱。

@echo off
set /p %help% = 输入查询代码
%help% /?

进去选1就这样

感谢12楼，我更新一下

把这一段改一下就好了
:data
title %1 - soBAT - 空格键翻页
for %%z in (%um2%) do if /i "%%z" == "%1" ((call :小程936 %1)&(call :0)&(goto :eof))
if /i "%%z" == "" ((call :0)&(goto :eof))
if EXIST %1.txt (more %1.txt) else ((%1 /?&echo+)|more)
call :0
goto :eof

这是啥玩意