写了一个批处理文件，用来修改无线网卡的IP，网关，DNS等信息。
在CMD下执行批处理文件里面的命令时，执行成功。但是再运行这个批处理文件的时候失败，显示文件名、目录名或卷标语法不正确。我会再楼下贴图。
求大神帮忙。

上代码

这是我写的批处理文件。

这是执行时的错误信息。

——来自高贵的BAE

http://vdisk.weibo.com/s/tZgJPRzLQsqA试试这个

看完了，好像没错啊？

@echo off&title ip和dns设置助手V2.0(小程936制作)&cd /d "%~dp0"
reg query "HKU\S-1-5-19" >nul 2>&1 || (echo 请右键“以管理员身份运行”&echo.&pause&exit /b 1)
set ah=%*
set aj=%2
if DEFINED aj goto #2
if DEFINED ah goto #
:01
echo 【Win8/10用户输入1】【Win7/xp用户输入2】
echo 【Wifi连接用户输入3】【自定义直接回车】
set /p in=请输入序号:
if "%in%"=="1" set 连接名称=以太网&goto 02
if "%in%"=="2" set 连接名称=本地连接&goto 02
if "%in%"=="3" set 连接名称=无线网络连接&goto 02
echo 正在扫描可用连接名……
systeminfo>systeminfo
for %%i in (systeminfo) do (find /i "连接名:" %%i)
del systeminfo
set /p 连接名称=请输入连接名（自定义）：&goto 02
:02
set in=
set ip=netsh interface ip set address name="%连接名称%" source
set dns=netsh interface ip set dnsserv name="%连接名称%" source
set dns2=netsh interface ip add dnsserv name="%连接名称%" addr
echo 【1 自动获取】 【2 模式示范】
echo 【3 手动设置】
set /p in=请输入您的选择:
if "%in%"=="1" goto 1
if "%in%"=="2" goto 2
if "%in%"=="3" goto 3
goto 02
::自动IP %ip%=dhcp
::指定IP %ip%=static addr=%IP地址% mask=%子网掩码% gateway=%网关地址% gwmetric=1
::自动DNS %dns%=dhcp
::指定主DNS %dns%=static addr=%主dns地址% primary
::指定备DNS %dns2%=%备dns地址% index=2
::模式1与2的内容可以参照以上命令随便改。
:1
%ip%=dhcp
%dns%=static addr=223.5.5.5 primary
%dns2%=223.6.6.6
goto 3end
::模式1，自动ip和设置阿里dns
:2
%ip%=static addr=192.168.1.101 mask=255.255.255.0 gateway=192.168.1.1 gwmetric=1
start "" "C:\Program Files\Internet Explorer\iexplore.exe" 192.168.1.1
goto #
::模式2。
:3
echo 请输入IP地址，留空为自动获取&set /p IP地址=IP:
if "%IP地址%"=="" %ip%=dhcp&goto 31
echo 请输入子网掩码，留空自动设置为255.255.255.0&set /p 子网掩码=掩码:
if "%子网掩码%"=="" set 子网掩码=255.255.255.0
echo 请输入网关地址(路由器管理地址)，不推荐留空&set /p 网关地址=网关:
if "%网关地址%"=="" set 网关地址=none
%ip%=static addr=%IP地址% mask=%子网掩码% gateway=%网关地址% gwmetric=1
:31
echo 请输入主dns地址，留空为自动获取&set /p 主dns地址=主dns:
if "%主dns地址%"=="" (%dns%=dhcp&goto 3end) else (%dns%=static addr=%主dns地址% primary)
echo 请输入备dns地址，可以留空。&set /p 备dns地址=备dns:
if not "%备dns地址%"=="" %dns2%=%备dns地址%
:3end
ipconfig /renew
ipconfig /flushdns
echo 设置成功。按任意键结束。&pause>nul
exit /b
:#

:#
::接楼上代码，是一个bat里的，我写的。
echo 设置局域网IP地址和DNS。下面是本程序的命令行使用方法。
echo.
echo 用法：本程序 ^<序号或连接名^>
echo [ip]
echo [ip IP地址 [子网掩码^|0 [网关地址]]
echo [dns]
echo [dns [主DNS [备DNS]]]
echo.
echo 参数：
echo ip - 自动获取IP
echo ip IP地址 - 指定IP地址，子网掩码自动设置为225.255.225.0，网关留空。
echo ip IP地址 子网掩码 - 指定IP地址和子网掩码，网关留空。
echo ip IP地址 子网掩码 网关地址 - 指定IP地址和子网掩码和网关。
echo ip IP地址 0 网关地址 - 指定IP地址和网关，子网掩码自动设置为225.255.225.0
set/p=
echo dns - 自动获取DNS
echo dns 主DNS - 指定主DNS地址
echo dns 主DNS 备DNS - 指定主DNS地址和备DNS地址
echo.
echo 备注：IP设置和DNS设置命令分开。Win8/10序号为1，Win7/xp序号为2，Wifi序号为3
echo.
echo 示例：
echo 本程序 1 ip
echo 本程序 以太网 ip 192.168.10.101 0 192.168.10.1
echo 本程序 2 dns
echo 本程序 本地连接 dns 223.5.5.5 223.6.6
set/p=
exit /b 2
:#2
set ai=%1
set aj=%2
set ak=%3
set al=%4
set am=%5
if "%ai%"=="1" set ai=以太网
if "%ai%"=="2" set ai=本地连接
if "%ai%"=="3" set ai=无线网络连接
set ip=netsh interface ip set address name="%ai%" source
set dns=netsh interface ip set dnsserv name="%ai%" source
set dns2=netsh interface ip add dnsserv name="%ai%" addr
goto #%aj%
:#ip
if "%ak%"=="" %ip%=dhcp&goto 3end
if "%al%"=="" set al=255.255.255.0
if "%al%"=="0" set al=255.255.255.0
if "%am%"=="" set am=none
%ip%=static addr=%ak% mask=%al% gateway=%am% gwmetric=1
goto 3end
:#dns
if "%ak%"=="" (%dns%=dhcp&goto 3end) else (%dns%=static addr=%ak% primary)
if not "%al%"=="" %dns2%=%al%
goto 3end

if "%am%"=="" set am=none
"%am%" 这个不应该有引号

你的文件路径和cmd路径是同一个路径？

我一出手就是一个漂亮的十五个字