题来！大佬速来！
左边原数据，右边2种格式目标表，不用辅助列，只用函数，生成目标表，单函数或者填充函数都行！

大佬们都放假了么？

=LET(
姓名, FILTER($A$2:$A$100, $A$2:$A$100<>""),
关系, FILTER($B$2:$B$100, $A$2:$A$100<>""),
组, SCAN(0, 关系, LAMBDA(a, v, a+(v="户主"))),
户主, FILTER(姓名, 关系="户主"),
结果, REDUCE({"户主","成员","成员数"}, SEQUENCE(ROWS(户主)), LAMBDA(a, g, VSTACK(a, HSTACK(INDEX(户主, g), TEXTJOIN("、", TRUE, FILTER(姓名, 组=g)), SUM(--(组=g)))))),
结果
)

=HSTACK(FILTER(A:A,B:B=B2),DROP(GROUPBY(SCAN(0,B2:B14,LAMBDA(x,y,IF(y=B2,x+1,x))),A2:A14,HSTACK(ARRAYTOTEXT,ROWS),,0),1,1))

=LET(a,SCAN("",B2:B13,LAMBDA(x,y,IF(y=B2,OFFSET(y,,-1),x))),DROP(GROUPBY(a,A2:A13,HSTACK(ARRAYTOTEXT,ROWS),0,0),1))
试试看

textsplit+textjoin

=LET(a,CONCAT(SCAN("",B2:B17,LAMBDA(x,y,IF(y=B2,"/"&OFFSET(y,,-1)&";",OFFSET(y,,-1)&",")))),c,DROP(TEXTSPLIT(a,";","/"),1),d,LEN(TAKE(c,,-1))-LEN(SUBSTITUTE(TAKE(c,,-1),",",""))+1,HSTACK(TAKE(c,,1),IFERROR(LEFT(TAKE(c,,-1),LEN(TAKE(c,,-1))-1),""),d))
有点啰嗦

1、=DROP(GROUPBY(SCAN(0,B2:B27="户主",SUM),A2:A27,HSTACK(SINGLE,LAMBDA(x,TEXTJOIN("、",,x)),ROWS),0,0),1,1)
2、=DROP(GROUPBY(SCAN(0,B2:B27="户主",SUM),A2:A27,HSTACK(SINGLE,LAMBDA(x,TEXTJOIN("、",,IFERROR(DROP(x,1),""))),ROWS),0,0),1,1)

样式1：=LET(a,SCAN(,A2:A31,LAMBDA(x,y,IF(OFFSET(y,,1)="户主",y,x))),DROP(GROUPBY(HSTACK(MATCH(a,UNIQUE(a),),a),A2:A31,HSTACK(ARRAYTOTEXT,ROWS),,0),1,1))
样式2：=LET(a,SCAN(,A2:A31,LAMBDA(x,y,IF(OFFSET(y,,1)="户主",y,x))),DROP(GROUPBY(HSTACK(MATCH(a,UNIQUE(a),),a),IF(B2:B31<>"户主",A2:A31,""),LAMBDA(x,HSTACK(TEXTJOIN(",",,x),ROWS)),,0),,1))
有谁能说出我的样式2的公式为什么没能把成员数算出来吗？和样式1一样，也是用ROWS算，两个数组用HSTACK堆起来。我自己没发现什么问题。大佬速速仙灵显灵！

样式2：=LET(n,SCAN(0,B2:B31,LAMBDA(x,y,x+(y="户主"))),m,SCAN(,A2:A31,LAMBDA(x,y,IF(OFFSET(y,,1)="户主",y,x))),DROP(GROUPBY(HSTACK(n,m),IF(B2:B31="户主","",A2:A31),HSTACK(LAMBDA(x,TEXTJOIN(",",,x)),ROWS),,0),1,1))